#include <amxmodx>
#include <oo>

#define main plugin_init

public oo_init()
{
  // 定義 Animal 類
  oo_class("Animal")
  {
      new cl[] = "Animal";

      oo_var(cl, "age", 1); // 為 Animal 定義變數 age 表示為這動物的年齡
      oo_var(cl, "name", 32); // 為 Animal 定義變數 name 表示為這動物的名字

      // 定義 Animal 的建構子得到名字和年齡的資料
      oo_ctor(cl, "Ctor", @str{name}, @int{age});

      // 定義 Animal 的解構子
      oo_dtor(cl, "Dtor");

      // 定義 MakeSound 方法 用以回傳這動物的聲音
      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      // 定義 GetLegs 方法 用以回傳這動物有多少條腿
      oo_mthd(cl, "GetLegs");

      // 定義 Introduce 方法 輸出這動物的自我介紹
      oo_mthd(cl, "Introduce");

      oo_smthd(cl, "Test"); // 靜態方法測試
  }

  // 定義 Dog 類繼承自 Animal 類
  oo_class("Dog", "Animal")
  {
      new cl[] = "Dog";

      // 定義建構子, 這會呼叫基類的建構子並輸入 Dog 作為名字
      oo_ctor(cl, "Ctor", @int{age});

      // 取代原本的 MakeSound 方法 回傳狗的叫聲
      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      // 取代原本的 GetLegs 方法 回傳狗有多少條腿
      oo_mthd(cl, "GetLegs");
  }

  // 定義 Cat 類繼承自 Animal 類
  oo_class("Cat", "Animal")
  {
      new cl[] = "Cat";

      // 定義建構子, 這會呼叫基類的建構子並輸入 Cat 作為名字
      oo_ctor(cl, "Ctor", @int{age});

      // 取代原本的 MakeSound 方法 回傳貓的叫聲
      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      // 取代原本的 GetLegs 方法 回傳貓有多少條腿
      oo_mthd(cl, "GetLegs");
  }

  // 同上
  oo_class("Bird", "Animal")
  {
      new cl[] = "Bird";

      oo_ctor(cl, "Ctor", @int{age});

      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      oo_mthd(cl, "GetLegs");
  }

  // 同上
  oo_class("Snake", "Animal")
  {
      new cl[] = "Snake";

      oo_ctor(cl, "Ctor", @int{age});

      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      oo_mthd(cl, "GetLegs");
  }
}

// Animal 的建構子
public Animal@Ctor(const name[], age)
{
  new this = oo_this(); // 獲取 this 物件的地址
  oo_set_str(this, "name", name); // 為動物的 name 變數賦以字串的值
  oo_set(this, "age", age); // 為動物的 age 變數賦以整數的值
}

// Animal 的解構子
public Animal@Dtor()
{
  new name[32];
  oo_get_str(oo_this(), "name", name, 32); // 獲取這動物的 name 變數的字串值
  server_print("%s 已經被人道毀滅.", name);
}

public Animal@MakeSound(msg[], len)
{
  // format the message to the msg[]
  formatex(msg, len, "我是一個動物");
}

public Animal@GetLegs()
{
  return 0;
}

public Animal@Introduce()
{
  new this = oo_this();

  new name[32];
  oo_get_str(this, "name", name, 32);

  new age = oo_get(this, "age"); // 獲取這動物的 age 變數的整數值

  new legs = oo_call(this, "GetLegs"); // 呼叫這動物的 GetLegs 方法, 獲取動物的腿數量

  // 呼叫這動物的 MakeSound 方法 and retrieve the result to the msg[]
  new msg[64];
  oo_call(this, "MakeSound", msg, charsmax(msg));

  server_print("你好, 我的名字是 %s, 現在 %d 歲, 有 %d 條腿, 我會說 %s", name, age, legs, msg);
}

public Animal@Test() { server_print("靜態方法測試"); }

public Dog@Ctor(age)
{
  // 呼叫父類 Animal 的建構子
  oo_super_ctor("Animal", "Dog", age);
}

public Dog@MakeSound(msg[], len)
{
  formatex(msg, len, "汪汪汪");
}

public Dog@GetLegs()
{
  return 4;
}

public Cat@Ctor(age)
{
  oo_super_ctor("Animal", "Cat", age);
}

public Cat@MakeSound(msg[], len)
{
  formatex(msg, len, "喵喵喵");
}

public Cat@GetLegs()
{
  return 4;
}

public Bird@Ctor(age)
{
  oo_super_ctor("Animal", "Bird", age);
}

public Bird@MakeSound(msg[], len)
{
  formatex(msg, len, "咕咕咕");
}

public Bird@GetLegs()
{
  return 2;
}

public Snake@Ctor(age)
{
  oo_super_ctor("Animal", "Snake", age);
}

public Snake@MakeSound(msg[], len)
{
  formatex(msg, len, "Sss sss");
}

public Snake@GetLegs()
{
  return 0;
}

public main()
{
  register_plugin("[OO] Animal", "0.1", "holla");

  // 建立物件
  new Animal:animals[5];
  animals[0] = oo_new("Dog", 7);
  animals[1] = oo_new("Cat", 6);
  animals[2] = oo_new("Bird", 4);
  animals[3] = oo_new("Snake", 3);
  animals[4] = oo_new("Animal", "Unknown", 0);

  for (new j = 0; j < 5; j++)
  {
      oo_call(animals[j], "Introduce"); // 為每一個物動呼叫自我介紹的方法
  }

  // Tests
  oo_call(0, "Animal@Test"); // Test calling the static method

  server_print("Object #%d %s a Snake", animals[3], oo_isa(animals[3], "Snake") ? "IS" : "IS NOT");
  server_print("Object #%d %s a Dog", animals[3], oo_isa(animals[3], "Dog") ? "IS" : "IS NOT");

  server_print("Class Dog %s a subclass of Animal", oo_subclass_of("Dog", "Animal") ? "IS" : "IS NOT");
  server_print("Class Animal %s a subclass of Cat", oo_subclass_of("Animal", "Cat") ? "IS" : "IS NOT");

  server_print("Class Bird %s exists", oo_class_exists("Bird") ? "IS" : "IS NOT");
  server_print("Class Fish %s exists", oo_class_exists("Fish") ? "IS" : "IS NOT");

  new class[32];
  oo_get_classname(animals[0], class, charsmax(class));
  server_print("Object #%d's classname is %s", animals[0], class);

  server_print("Object #%d %s exists", animals[0], oo_object_exists(animals[0]) ? "IS" : "IS NOT");

  for (new j = 0; j < 5; j++)
  {
      oo_delete(animals[j]); // Delete each animal objects
  }

  server_print("Object #%d %s exists", animals[0], oo_object_exists(animals[0]) ? "IS" : "IS NOT");
}

你好, 我的名字叫 Dog, 現在 7 歲, 我有 4 條腿, 我會說 汪汪汪
你好, 我的名字叫 Cat, 現在 6 歲, 我有 4 條腿, 我會說 喵喵喵
你好, 我的名字叫 Bird, 現在 4 歲, 我有 2 條腿, 我會說 咕咕咕
你好, 我的名字叫 Snake, 現在 3 歲, 我有 0 條腿, 我會說 Sss sss
你好, 我的名字叫 Unknown, 現在 0 歲, 我有 0 條腿, 我會說 我是一個動物
靜態方法測試
Object #2102251586 IS a Snake
Object #2102251586 IS NOT a Dog
Class Dog IS a subclass of Animal
Class Animal IS NOT a subclass of Cat
Class Bird IS exists
Class Fish IS NOT exists
Object #16934577's classname is Dog
Object #16934577 IS exists
Dog 已經被人道毀滅
Cat 已經被人道毀滅
Bird 已經被人道毀滅
Snake 已經被人道毀滅
Unknown 已經被人道毀滅
Object #16934577 IS NOT exists