下面是引用 acc8087 於 2010-01-22 12:13 發表的 : 
我的意思是怎樣作出那麼好的作品 可以執行在遊戲上或者是軟體上的
另外:之前您交過我的 但 我做出來時 其它的卻會被動到 要怎麼條到能被使用到呢 ??
也就是其它地區都不會被弄到 還有大小的調整 @@" 附註:就是說:做好一個程式能
向另一外邊的好看又能用的 圖 
還是聽不懂.....不過，反正我也閒來無聊
，做了個模仿 選項的表單
你可以照底下的圖 依序建立 元件，但 INDEX 記得打對，且 哪個元件在哪個 父元件內 要弄好，位置可以亂丟
我只有用元件的位置，觸發事件我就不做了，雖然才一個小小的選項，還是有點累......
我把程式的檔案放在附件中了
複製程式碼後請把
& quot ; 全部取代成
" (如果有的話)
複製程式
Private Sub Form_Load()
Dim i As Long
Dim ArrCheckText()
Dim ArrTabText()
Dim ArrCMDText()
'____________________ Obj Ini. ______________________
'--------- Apply String Into Array-String ----------
ArrCheckText = Array("自動進行語法檢查(K)", "要求變數宣告(R)", "自動列出成員(L)", "自動使用快速諮詢(Q)", "自動顯示資料提示(S)", _
"自動縮排(I)", "編輯時可使用拖放方式移動文字(D)", "預設為全模組檢視(M)", "顯示程序分隔線(P)")
ArrTabText = Array("編輯器", "撰寫風格", "一般 ", "停駐", "環境", "進階")
ArrCMDText = Array("確定", "取消", "說明")
'------- Pre-Set -------
SSTab1(0).Style = ssStylePropertyPage
'------ Load More Obj. ------
For i = 0 To 8
If i <> 0 And i < 6 Then Load Check1(i)
Check1(i).Caption = ArrCheckText(i)
Check1(i).Value = 1
Check1(i).Width = (Me.TextWidth(ArrCheckText(i)) + 250) * 1.05
Check1(i).Visible = True
Next i
'-------- CMD ---------
For i = 0 To 2
If i <> 0 Then Load Command1(i)
Command1(i).Height = 300
Command1(i).Width = 1130
Command1(i).Caption = ArrCMDText(i)
Command1(i).Visible = True
Next i
'--------- Form ---------
With Me
.Icon = Nothing
.BorderStyle = 3
.Caption = "選項"
.AutoRedraw = True
.Width = 6480
.Height = 5000
End With
'------- SSTab -------
With SSTab1(0)
.Tab = 0
.Tabs = 6
.TabsPerRow = 6
For i = 0 To 5
.TabCaption(i) = ArrTabText(i) & IIf(i >= 2, " " & vbCr & vbTab, "")
Next i
.Top = 120
.Left = 120
.Width = Me.ScaleWidth - 120 * 2
.Height = Me.ScaleHeight - Command1(0).Height - 120 * 2.3
.TabMaxWidth = 500
End With
'----- Frame1 ---------
With Frame1(0)
.Caption = "程式撰寫設定"
.Top = 120 * 1.5 + SSTab1(0).TabHeight
.Left = 120 * 1.5
.Width = SSTab1(0).Width - 120 * 5
Check1(0).Top = 120 * 2.5
Check1(0).Left = 150
For i = 1 To 4
Check1(i).Top = Check1(i - 1).Top + Check1(0).Height
Check1(i).Left = Check1(i - 1).Left
Next i
Check1(5).Left = 2900
Check1(5).Top = Check1(0).Top
.Height = Check1(4).Top + Check1(4).Height + 120
End With
With Frame1(1)
.Caption = "視窗設定"
.Left = Frame1(0).Left
.Top = Frame1(0).Top + Frame1(0).Height + 150
.Width = 3400
.Height = 1160
Check1(6).Top = 120 * 2.5
Check1(6).Left = 150
For i = 7 To 8
Check1(i).Top = Check1(i - 1).Top + Check1(0).Height
Check1(i).Left = Check1(i - 1).Left
Next i
End With
'------------ Label & Text --------------
Label1(0).Top = Check1(1).Top + 150
Label1(0).Left = Check1(5).Left
Label1(0).Caption = "定位點寬度(T): "
Text1(0).Left = Label1(0).Left + Label1(0).Width + 120 * 1
Text1(0).Text = 4
Text1(0).Top = Label1(0).Top
Text1(0).Width = 120 * 8
Text1(0).Height = 300
'---------- CMD --------------
Command1(0).Left = SSTab1(0).Left + SSTab1(0).Width - Command1(0).Width * 3 - 90 * 2
Command1(0).Top = SSTab1(0).Top + SSTab1(0).Height + 70
For i = 1 To 2
Command1(i).Top = Command1(i - 1).Top
Command1(i).Left = Command1(i - 1).Left + Command1(i - 1).Width + 90
Next i
Command1(0).Default = True
End Sub
